Example 2: Constrained Optimization (Example 5)

This problem involves finding the maximum and minimum values of the function

> f := 2+x^2+y^2;

>

on the set of points bounded by the ellipse

> S := x^2 + y^2/4 = 1;

>

Graphically, the surface is

> Pf := plot3d( f, x=-3..3, y=-3..3, orientation=[30,60] ):

> Pf;

>

Because the origin is contained inside the ellipse, the global minimum occurs at (0,0). The global maximum is not yet apparent. For this, graph the boundary of the ellipse in the x-y plane

> Sparam := [ cos(theta), 2*sin(theta), 0 ];

> PS := spacecurve( Sparam, theta=0..2*Pi, color=black ):

> PS;

>

and on the surface itself

> fSparam := [cos(theta),2*sin(theta),eval(f,{x=cos(theta),y=2*sin(theta)})];

> PfS := spacecurve( fSparam, theta=0..2*Pi, color=red ):

> PfS;

>

>

From this picture it is clear that there are two maxima and two minima of f along the ellipse. The maxima should be global maxima while these minima will not be lower than the value at the critical point, i.e., the origin. The following pictures are also helpful:

> display( [PfS,PS] );

> display( [Pf,PfS,PS] );

>

To conclude, let's locate the extrema via calculus. First, find the critical points:

>

> fx := diff( f, x );

> fy := diff( f, y );

>

> crit_pt := solve( {fx=0,fy=0}, {x,y} );

Note: This was simple enough to do by inspection.

>

To classify this critical point:

> fxx := diff( f, x,x );

> fyy := diff( f, y,y );

> fxy := diff( f, x,y );

> discr := fxx*fyy - fxy^2;

>

Because D>0 and fxx>0, the critical point is a local miminum.

>

To locate the exxtrema around the ellipse, use the parameterization of the ellipse to obtain an expression for the value of the function at any point on the ellipse:

> fS := eval( f, {x=cos(theta),y=2*sin(theta)} );

>

> plot( fS, theta=0..2*Pi );

>

This plot shows the two maxima and two minima seen previously in the 3D plots. An analytic determination of these points is not difficult.

> DfS := diff( fS, theta );

> solve( DfS=0, theta );

>

Maple gives its answers outside our parameter range, but we know we can add 2*Pi to these answers and obtain equivalent points.

> fS1 := eval( fS, theta=0 );

> fS2 := eval( fS, theta=Pi/2 );

> fS3 := eval( fS, theta=Pi );

> fS4 := eval( fS, theta=3*Pi/2 );

>

The value of the function at the critical point is:

> fCP := eval( f, crit_pt );

>

Based on these values, it is seen that the global minimum is 2 and occurs at (0,0) and the global maxiumum is 6 which occur at (0,2) and (0,-2) (i.e., when = /2 and 3 /2).

>