1.

>

restart;

>

>	f := sqrt(x); g := exp(-3*x);

>

>	plot( [f,g], x=0..1 );

>

>	c := solve( f=g, x );

>	c := fsolve( f=g, x );

>

(a) Area of R

>	A := Int( f-g, x=c..1 );

>	A = value( A );

>

(b) Volume of solid formed when R is revolved around y=1

>	with( Student[Calculus1] );

>	VolumeOfRevolution( 1-g, 1-f, x=c..1, output=integral );

>	VolumeOfRevolution( 1-g, 1-f, x=c..1, output=plot, view=[0..1,-1..1,DEFAULT] );

>	VolumeOfRevolution( 1-g, 1-f, x=c..1, output=value );

Note: The VolumeOfRevolution command is available through a friendly graphical user interface (GUI) via the WWW. Links are provided on the course website. (You can use the Maplet link if you have Maple 8 on the computer you are using; otherwise, assuming you have an Internet connection, use the MapleNet link.)

>

>	V := Int( Pi*(1-g)^2 - Pi*(1-f)^2, x=c..1 );

>	V = value( V );

>

(b) Volume of solid with R as base and height = 5*base for all cross-sections.

>	plot3d( 5*(f-g), y=g..f, x=c..1, axes=boxed, shading=z );

>

>	V2 := Int( (f-g)*5*(f-g), x=c..1 );

>	V2 = value( V2 );

>

>

2.

>

restart;

>	V := -(t+1)*sin(t^2/2);

>	plot( V, t=0..3 );

>

(a) Find a(2).

>	A := diff( V, t );

>	a(2) = eval( A,t=2 );

>	evalf( % );

At this time the velocity is negative and increasing. The speed is the absolute value of the velocity.  At t=2, the speed is positive, and decreasing.

>	plot( [V,abs(V)], t=0..3,       style=[point,line],       color=[red,blue],       legend=["velocity","speed"] );

>

(b) Find times when particle changes direction

Direction change occurs when velocity changes sign. From graph, this occurs exactly once in [0,3], near t=2.5.

>	solve( V=0, t );

>	fsolve( V=0, t );

>	fsolve( V=0, t=2..3 );

>

(c) Find total distance travelled.

>	TotDist := Int( abs(V), t=0..3 );

>	TotDist = value( TotDist );

>	TotDist = evalf( TotDist );

>

(d) Find greatest distance from particle to origin during 0 <= t <= 3.

The position of the particle can be given as:

>	P := 1 + Int( V, t=0..T );

>	plot( P, T=0..3 );

>

The greatest distance from the origin occurs at the critical point near t=2.5. Note that this critical point for the position occurs at the same time that the particle changes direction

>	Tcrit := fsolve( V=0, t=2..3 );

>	MaxSep := eval( P, T=Tcrit );

>	evalf( MaxSep );

Thus, the maximum separation from the origin is 2.265 (units).

6.

>

restart;

>	f := piecewise( x<=3, sqrt(x+1), x<5, 5-x );

>

(a)

>	plot( f, x=0..5 );

>

(b)

>	AvgVal := 1/5 * Int( f, x=0..5 );

>	AvgVal = value( AvgVal );

>

>	plot( [f, AvgVal], x=0..5 );

>

(c)

>	g := piecewise( x<=3, k*sqrt(x+1), x<=5, m*x+2 );

>

g differentiable at x=3 means that i) g is continuous at x=3 and ii) g' is continuous at x=3.

>	q1 := Limit( g, x=3, left ) = Limit( g, x=3, right );

>	eq1 := value( q1 );

>

>	Dg := diff( g, x );

>	q2 := Limit( Dg, x=3, left ) = Limit( Dg, x=3, right );

>	eq2 := value( q2 );

>

>	solve( {eq1,eq2}, {k,m} );

>

>	G := eval( g, {k=8/5,m=2/5} );

>	plot( G, x=0..5 );

>