Purpose

>

Asymptotes of a function have a variety of uses. The primary use in this course is as one step in the creation of a graph of the function over a large interval without evaluating the function at too many points. You are likely to encounter the same ideas in courses dealing with complexity analysis of algorithms and differential equations.

Remember that it should not be necessary for you to do too much typing to complete this project. Except for entering specific functions, all of the Maple code needed should be available somewhere within this worksheet. Please see Jay, Wally, or Professor Meade if you have any questions.

The laboratory project begins with an investigation of horizontal and vertical asymptotes using Maple. The first example is one of your homework problems from Section 2.8. The first problem which you will be solving is an example worked in class last Friday (6 September). Maple will be used to evaluate limits and to produce graphs. The second part of the lab introduces the oblique asymptote. This is a situation in which the symbolic capabilities within Maple can be a considerable time saver..

Before submitting your report check that you have answered each part of the exercises.

The project is due in the dropbox at midnight, Thursday, 12 September 2002 . Do not put off work on this project until Thursday night!

>

Exercise 1 : Horizontal and Vertical Asymptotes

>

To illustrate the use of Maple to create a plot of a function and its horizontal and vertical asymptotes, consider the function

>	F := 3/(9-x^2);

>

If we ask Maple to plot this function on the interval [-10, 10 ], we will see

>	plot( F, x=-10..10 );

>

This plot looks somewhat like the output from an echocardiogram (EKG). We have seen similar plots in earlier labs. It is produced because Maple simply plots points and then connects the dots. To see only the points in the plot, position the cursor on top of the plot and click the left mouse button. Then, select Point  under the Style  menu --- or click on the blue sine-like icon in the context bar. The horizontal and vertical asymptotes of this example fairly apparent in this graph:

horizontal asymptote:           

vertical asymptotes: ,  

Sometimes it will be helpful to know the asymptotes before plotting the function.

>

The search for horizontal asymptotes is simpler in that it depends only on the evaluation of two limits.

>	asymp_H := { y=limit( F, x=infinity ), y=limit( F, x=-infinity ) };

>	plot_H := implicitplot( asymp_H,

>	x=-10..10, y=-20..20,

>	style=point, color=green ):

>

plot_H;

>

For this example the vertical asymptotes occur at the zeros of the denominator:

>	q1 := solve( denom(F)=0, {x} );

>	asymp_V := map( op, {q1} );

>	plot_V := implicitplot( asymp_V,

>	x=-10..10, y=-20..20,

>	style=point, color=blue ):

>

plot_V;

>	plot_fn := plot( F, x=-10..10, y=-20..20, discont=true ):

>

plot_fn;

>

When all three plots are assembled as one plot,the result is

>	display( [ plot_H, plot_V, plot_fn ] );

>

Notes:

• In general, the search for vertical asymptotes must include any points where the function is not defined. For trigonometric functions this includes, but is not limited to, odd multiples of  for the tangent and secant functions.
• The extra step of converting the list of sets of solutions into a single set of equations of vertical lines will make it easier to plot all vertical asymptotes at one time.
• The third argument in the plot  command is an optional argument that specifies the vertical window for the plot. The vertical window is normally selected automatically by Maple to ensure that all points fit in the display. However, for functions with vertical asymptotes this results in a window that is so large that important details are rendered invisible.
• The final argument in the plot  command, discont=true , is an optional argument that instructs Maple to look for discontinuities in the function and to not connect the points on either side of this discontinuities.

>

Determine the horizontal and vertical asymptotes for the graphs of the functions listed below. Your report should include a summary of the asymptotes and a plot of the function with an appropriately selected window (both horizontal and vertical).

>

Exercise 2 : Oblique Asymptotes

>

An oblique asymptote  to the graph of  is a straight line  where either   or   . In addition to aiding in the graphing of a function, oblique asymptotes can be used to obtain a simple approximation to the function for very large (or very small) values of its argument. Note that if  then the oblique asymptote is actually a horizontal asymptote. This means that oblique asymptotes generalize the horizontal asymptotes discussed in Exercise 1.

To illustrate the concept of oblique asymptote, the oblique asymptote for the following function will be found and plotted together with the vertical asymptotes

>	F := ( 2*x^4 + 3*x^3 - 2*x - 4 ) / ( x^3 - 1 );

>

Begin, as usual, by asking Maple for a plot of the function. After a little trial-and-error, the following options are found to provide a reasonable picture.

>	plot( F, x=-10..10, y=-20..20, discont=true );

>

Notice the vertical asymptote near  and how the graph resembles a straight line for large and small values of . This straight line is the oblique asymptote for this problem.

>

To find an oblique asymptote one general begins by performing long division on the rational function. This is a simple but tedious step that is ideally performed by Maple. The quo  and rem  commands can be used to find the quotient and remainder when two polynomials are divided. The quotient of the numerator and denominator of the original rational function is the oblique asymptote for the function:

>	q := quo( numer(F), denom(F), x );

>	r := rem( numer(F), denom(F), x );

>

This means that it should be possible to re-write the original function as

>	FF := q + r/denom(F);

>

To verify Maple's calculuation,

>	normal(FF) = F;

>

To confirm that the quotient of the numerator and denominator of this rational function is the oblique asymptote, check against the definition:

>	limit( F-q, x=infinity );

>	limit( F-q, x=-infinity );

>

Observe that these results are consistent with a plot of  :

>	plot( F-q, x=-10..10, y=-10..10, discont=true );

>

Remember that we are not interested in the behavior for "small" values of , only as .

We conclude by storing this result and the corresponding plot for later use.

>	asymp_O := { y = q };

>	plot_O := implicitplot( asymp_O,

>	x=-10..10, y=-20..20,

>	style=point, color=green ):

>

plot_O;

>

Vertical asympotes can be found as before.

>	q1 := solve( denom(F)=0, {x} );

>

Note that Maple returns all three solutions to , not just the real-valued solution. To extract all complex-valued solutions one might use the following command to remove all solutions that contain the :

>	q2 := op(remove( has, {q1}, I ));

>	asymp_V := map( op, {q2} );

>	plot_V := implicitplot( asymp_V,

>	x=-10..10, y=-20..20,

>	style=point, color=blue ):

>

plot_V;

>

>	plot_fn := plot( F, x=-10..10, y=-20..20, discont=true ):

>	display( [ plot_O, plot_V, plot_fn ] );

>

Determine the oblique and vertical asymptotes for the graphs of the functions listed below. Your report should include a summary of the asymptotes and a plot of the function with an appropriately selected window (both horizontal and vertical).

>

Exercise 3. Nonlinear asymptotics

Consider the function

>	F := sqrt( 3*x^3+1 ) / (2*x + 1);

>

Exercise 4.

Maple contains a built-in command to find horizontal, vertical, and oblique asymptotes. Find the name of this command. Use this command to verify the results of one of the examples in Exercises 1 and 2. Include the full Maple command(s) and their output in your report.

>