Work.mws

Work

>    restart;
with( plots ):

Warning, the name changecoords has been redefined

>   

Lesson Overview

Work can be a difficult physical concept to master.  One problem is that the common usage of work is different from the physical definition.  Work is done anytime a force moves an object.  Assuming the force is constant, and in the direction of the motion, the work done by the force is the product of the force, F , and the distance the object is moved, d :

   W = F*d .  

When the force is not constant, the work can be computed as a definite integral.  The slice, approximate, limit, evalute process is used to determine the appropriate definite integral.  The key is to slice the motion from x = a  to x = b  into n segments with lengths Delta*x[i] = x[i]-x[i-1] .  Assuming the force is continuous, the force on each slice can be approximated by the force at, say, the initial position for each slice:

   Delta*W[i]  = F(x[i-1])*(x[i]-x[i-1])  = F(x[i-1])*Delta*x[i] .  

When these works are summed, and all Delta*x[i] 's shrink to zero, work is seen to be the definite integral:

  W = Limit(Sum(Delta*W[i],i = 1 .. n),max(Delta*x[i]) = 0)   

   `                 ` = Limit(Sum(F(x[i-1])*Delta*x[i],i = 1 .. n),max(Delta*x[i]) = 0)   

   `` = Int(F(x),x = a .. b) .                        

>   

Example 1: Linear Spring (Hooke's Law)

Hooke's Law

Consider a spring which, at equilibrium, has natural length L .  Hooke's Law states that the force, F , needed to stretch (or compress) a spring to a new length, x , is

>    F[Hooke] := k*(x-L):
F = F[Hooke];

F = k*(x-L)

where the spring constant, k , is a positive number that represents the stiffness of the spring.  (A stiff spring requires a greater force to stretch/compress the spring from equilibrium, hence k  is larger for stiffer springs.)

>   

Problem

Suppose it requires w[1]  Joule (newton-meter) of work to stretch a spring from length l[1]  to length l[2]  and another w[2]  Joule of work to stretch the spring from length l[2]  to length l[3] .  Find formulae for the spring constant, k , and natural length of the spring, L .

>   

Solution

By Hooke's Law, the force needed to stretch the spring is

>    F = F[Hooke];

F = k*(x-L)

The information given leads to two equations for the two unknowns, k  and L .  The work needed to stretch the spring from length l[1]  to l[2]  is given by the integral

>    Work1a := Int( F[Hooke], x=l[1]..l[2] ):
Work1a;

Int(k*(x-L),x = l[1] .. l[2])

Evaluating this integral leads to the first of our equations:

>    eq1a := w[1] = value( Work1a ):
eq1a;

w[1] = 1/2*k*(l[2]^2-l[1]^2)-k*L*(l[2]-l[1])

In exactly the same way, the work needed to stretch the spring from length l[2]  to l[3]  is

>    Work1b := Int( F[Hooke], x=l[2]..l[3] ):
Work1b;

Int(k*(x-L),x = l[2] .. l[3])

The corresponding equation for k  and L  is

>    eq1b := w[2] = value( Work1b ):
eq1b;

w[2] = 1/2*k*(l[3]^2-l[2]^2)-k*L*(l[3]-l[2])

>   

The solution to these equations can be determined manually when these equations are factored:

>    factor( eq1a );
factor( eq1b );

w[1] = 1/2*k*(-l[2]+l[1])*(-l[2]+2*L-l[1])

w[2] = 1/2*k*(-l[3]+l[2])*(-l[3]+2*L-l[2])

Now, dividing the two equations eliminates k  and leads to a linear equation satisfied by L .  Once this is solved, k  can be found by inserting the formula for L  into either equation.  Rather than spend time on these simple (but messy) calculuations, let's let Maple do the work (pun intended!) for us:

>    sol1 := solve( {eq1a,eq1b}, {k,L} );

sol1 := {k = 2*(-w[2]*l[2]+w[2]*l[1]+l[3]*w[1]-l[2]*w[1])/(-l[3]^2*l[2]+l[3]^2*l[1]-l[2]^2*l[1]+l[3]*l[2]^2-l[3]*l[1]^2+l[2]*l[1]^2), L = 1/2*(w[2]*l[1]^2-w[1]*l[2]^2-l[2]^2*w[2]+w[1]*l[3]^2)/(-w[2]*l[...

In particular, if

>    paramA := [
   w[1] = 0.06,   # work (J)
   w[2] = 0.12,   # work (J)
   l[1] = 0.07,   # first length (m)
   l[2] = 0.10,   # intermediate length (m)
   l[3] = 0.13    # final length (m)
          ]:

then the two equations become

>    eq1A := eval( eq1a, paramA ):
eq1B := eval( eq1b, paramA ):
eq1A;
eq1B;

.6e-1 = .2550000000e-2*k-.3e-1*k*L

.12 = .3450000000e-2*k-.3e-1*k*L

>    solve( { eq1A, eq1B }, { k, L } );

{L = .5500000000e-1, k = 66.66666667}

Thus, the natural length of this spring is L = 5.5  cm and the spring constant is k = 66.67  N/m.

>   

>   

In general, Hooke's Law applies only when the displacement from natural length is not too great.  One extreme case is when the spring is stretched to the full length of coils. Beyond this length the spring must break; many springs will break much earlier.  At the other extreme, the spring cannot be compressed to a length shorter than that when the coils are physically touching.  Hooke's Law stops applying well before either of these cases is encountered.  A nonlinear spring law of some sort will apply for displacements between those where the linear Hooke's Law applies and the extreme limits. This subject is most likely to be studied in more detail in Physics or Engineering courses.

>   

Example 2: Electrical Charge (Coulomb's Law)

Coulomb's Law

Coulomb's Law states that the repulsive force between two identical electrical charges is inversely proportional to the square of the distance between the charges.  That is,

>    F[Coulomb] := -C/d^2:
F = F[Coulomb];

F = -C/d^2

where d  is the distance between the charges and C  is the (positive) constant of proportionality.  The minus sign is present to remind us that this force is repulsive.

>   

Notes

  • Each charge is assumed to be concentrated at a single point.
  • A typical unit for measuring electical forces is the dyne, with units gram centimeter per second squared.

>   

>   

Problem

Suppose the force of repulsion between two particles is F = -14  dynes when the particles are R = 7  cm apart.  How close can the two charges be brought together without using more than 500 dyne cm of work?

>   

Solution

First, the information about the force when the particles are separated by 7 cm provides an opportunity to determine the constant C :

>    q1 := eval( F=F[Coulomb], [F=-14,d=7] );

q1 := -14 = -1/49*C

>    solC := isolate( q1, C ):
solC;

C = 686

That is, C = 686  dyne cm ``^2 .

>   

The work required to move the particles with an original separation of R  cm to a configuration with separation r  cm can be computed as a definite integral.  To ensure that the correct definite integral is obtained, utilize the slice, approximate, limit, evaluate process.  Partition the interval [ r , R  ] into subintervals with endpoints r = x[0]  < x[1]  < x[2]  < ... < x[n] = R .  The (positive) work required to reduce the separation from x[i+1]  to x[i]  is Delta*W[i]  = F(x[i]^`*`)*(x[i]-x[i+1])  = ( -C/((x[i]^`*`)^2) ) ( -Delta*x[i] ) = C/((x[i]^`*`)^2)   Delta*x[i] .  When these approximations are summed, and the appropriate limit is taken, the total work is seen to be given by the integral

>    Work2 := Int( -F[Coulomb], d=r..R ):
Work = Work2;

Work = Int(C/d^2,d = r .. R)

Note that the work is positive when R  > r  and negative when R  < r .  This is as expected for a repulsive force.

>   

This problem limits the movement of the particles based on the total amount of work expended.  When all know information is inserted into the definite integral for the total work and this integral is evaluated the following equation for the final separation, r , is obtained:

>    q1 := eval( Work=Work2, [Work=500,R=7,solC] ):
q2 := value( q1 ):
q1;
`` = rhs( q2 );

500 = Int(686/d^2,d = r .. 7)

`` = -98*(r-7)/r

This equation is easily solved to obtain

>    solr := isolate( q2, r ):
solr;
`` = evalf( rhs(solr) );

r = 343/299

`` = 1.147157191

This means that 500 dyne cm of work is required to bring the particles from a separation of 7 cm to a separation of (approximately) 1.147cm.

>   

>   

Example 3: Pumping A Liquid

Problem 1

A cylindrical bottle is filled with a cooking oil (at room temperature).  Assuming the bottle has a circular base with radius 4 cm and height 10 cm, find the work required to pump all of the oil out of the bottle.  (At room temperature, the standard density of cooking oil, including olive, sunflower, coconut, corn, palm, and peanut oils, is close to delta = .92  gm/cm ``^3 .)

Solution

The work required to pump a thin slice of oil at height y  ( 0 < y  < 10 ) in the bottle out of the bottle is approximate the weight of the slice times the distance to the top of the bottle.  The distance to the top of the bottle is 10-y.  The weight of the slice is

  `(density)`*`(cross-sectional area)`*`(thickness)`  = delta   ( Pi*4^2 )   Delta*y .  

Thus,

   Delta*W  = delta  ( 16*Pi  ) Delta*y  ( 10-y  ).  

When the contributions to the work from each thin slice with 0 < y  < 10 are summed and limits taken, the total work is seen to be represented by the definite integral

>    Work3a := Int( delta*16*Pi*(10-y), y=0..10 ):
Work = Work3a;

Work = Int(16*delta*Pi*(10-y),y = 0 .. 10)

When this integral is evaluated, and the value for the density is substituted into the result, the total work is found to be

>    Work = evalf( eval( value(Work3a), delta=0.92 ) );

Work = 2312.212193

The total work is 2312.2 g-cm.

>   

Problem 2

Consider the same problem except that the bottle is a right circular cone with base radius 4 cm and height 10 cm.

>   

Solution

The only difference in the setup for this problem is that the cross-sectional area of each thin slice depends on the height y .  To be specific, at height y  ( 0 < y  < 10 ), the cross-section is a circle with radius r = 4-2*y/5 .  The weight of the corresponding slice with thickness Delta*y  is delta  ( Pi*(4-2*y/5)^2  ) Delta*y .  

>    Work3b := Int( delta*(Pi*(4-2*y/5)^2)*(10-y), y=0..10 ):
Work = Work3b;
`` = evalf( eval( value(Work3b), delta=0.92 ) );

Work = Int(delta*Pi*(4-2/5*y)^2*(10-y),y = 0 .. 10)

`` = 1156.106097

>   

Followup Question

Is it reasonable that the work in Problem 2 is exactly half the work in Problem 1?

>   

>   

>   

Lesson Summary

Work can be computed as definite integral in which the integrand is the force acting on the object and the limits of integration are the initial and final positions of the object:

   W = Int(F(x),x = a .. b) .  

What's Next?

This concludes the unit on applications of integrals. While there are many more applications of derivatives, the ones presented in this unit provide a foundation from which you should be able to understand most other applications.

The assigned problems from the text provide additional problems similar to the three examples worked in this lesson.  The online homework assignment contains additional problems of this type as well as questions to test your conceptual understanding of work.  Remember to take advantage of the practice sessions prior to starting the graded online homework assignment.

As this concludes this unit, there is an online quiz. Quiz 10 contains questions pertaining to the Volume of a Solid, Length of a Plane Curve, and Work lessons.

There is no next lesson!  This is the end of the course!!  Congratulations!!!

>   

>   

>